From b2c921ee7b574eb92d9a9dec68098f781c7314e0 Mon Sep 17 00:00:00 2001
From: David Harris <david_harris@hmc.edu>
Date: Thu, 12 May 2022 04:31:00 +0000
Subject: [PATCH] Added examples/asm/trap trap handler example

---
 examples/asm/trap/Makefile              |  19 ++++
 examples/asm/trap/trap                  | Bin 0 -> 7240 bytes
 examples/asm/trap/trap.S                | 131 ++++++++++++++++++++++++
 examples/asm/trap/trap.reference_output |   6 ++
 4 files changed, 156 insertions(+)
 create mode 100644 examples/asm/trap/Makefile
 create mode 100755 examples/asm/trap/trap
 create mode 100644 examples/asm/trap/trap.S
 create mode 100644 examples/asm/trap/trap.reference_output

diff --git a/examples/asm/trap/Makefile b/examples/asm/trap/Makefile
new file mode 100644
index 00000000..6e9f1b47
--- /dev/null
+++ b/examples/asm/trap/Makefile
@@ -0,0 +1,19 @@
+TARGET = trap
+
+$(TARGET).objdump: $(TARGET)
+	riscv64-unknown-elf-objdump -D $(TARGET) > $(TARGET).objdump
+    
+$(TARGET): $(TARGET).S Makefile
+	riscv64-unknown-elf-gcc -g -o $(TARGET) -march=rv64gc -mabi=lp64 -mcmodel=medany \
+	    -nostartfiles -T../../link/link.ld $(TARGET).S
+
+sim:
+	spike +signature=$(TARGET).signature.output +signature-granularity=8 $(TARGET)
+	diff --ignore-case $(TARGET).signature.output $(TARGET).reference_output || exit
+	echo "Signature matches! Success!"
+
+clean:
+	rm -f $(TARGET) $(TARGET).objdump $(TARGET).signature.output
+
+
+
diff --git a/examples/asm/trap/trap b/examples/asm/trap/trap
new file mode 100755
index 0000000000000000000000000000000000000000..1d7d3bbc6df2110efb0e4c30fb76c2173bb0e7a2
GIT binary patch
literal 7240
zcmeHMPiP!f82@HwHztiub`vE+58Y&~_;)jI*H%PjlaQK18f#-jP~6VWPO?LGcb1t+
znt<Sv5}|lW&7p#zUW6Pfh#-2Z5-;M-gBK5i=s~^2v_%B9@%!F;Gnsu!s0EMnh5i2g
zzCZ8H_ujq@Z{8T6Jf$iM1f;?Z5LSz@A~B?|@8gnuMR*ca<UMeh#U{y>;(p{Up)q+=
z7=aAps7{CQF_95@fed^Jq3qTVJh6;B5O*N%K-_`2191o94#XXZI}mpu?m*muxC3zq
z{$mFQ1_AmNB{OgYW%paK1?Ll2RDkuB&7`+>PWMteelq&H3Z35CsD5RLeCjjanp*JA
zCv;`p!;x0Y|MdOzzIrRotQR&u+XVH;{K+v;FMgs@d`DKFhLx5AUY}aX>gOQ)bothe
zp-jQc>S(_L*}^=GberF)u=RWC?|V1AY^spfyi|W-aBThhX0Lg<tX>{9J7!eVoPqSl
zrSiKgYRmgr)em3FCA~~i*N(63T+FL%1P?O$KtDc_W?o+%rLmO{4sOWSwU2(dlh4Qr
ztmWFCxd_Ums3zUT69qfp)Jt_@2C-RU6=Ehb=u{4MZ{VFr5<1~wOi>i&uO7TTK_ZI*
zM@a=$IjZ)mkC4h3bm407yAiEV(Uh)EP&7^O1nL}7y10H2rz{?m5RodYL-8sOLEc@2
z>pWf)-j1-s-m#Lm8GY}pqGORa7==gj`N+B!nR#>$L2h)0d!I<2Lr{%(CY%qoTTzCq
zPTd-=8ZIvLFk9-!E*Q1i^02jJ)SETS8#cW9u<sg8AeNhkW4KC5P&#Sh*g^)Y_6M`>
zLNiaUmXe0lKw9bR)q0Nf9P8<4w`b_#MEi*r9B`uuYLWa+7_tzf-@$yJo0`dtOlR`B
z<0s`}lC9B$q{O{k#HY~=<$F5xYxuVxX}~V=TCz{WhV4gM`^{h&q5*YrFKN5IYIADP
z)n*5V28RMQl(a|**xm^Nq1?^n_RgPQh-DFYpTMEmj^i<kg#8(6@7n_mS0E+zla3M^
z`6XzN9~F30!k=e2*1x|!{xuO_l;Z0GpOA1<;8PM_75Fa_?h5=J34dMSZ%g=_0{=$B
zF%BsKS0x<lGW>f9|4`tcOZa;X-@89Q6?muA=W7h#-YGJ<%f4c&0!1nQTf|d1Pox&H
zfPO|LMe8f|A53%Z>=UQ#Le7CRFP=U#&iUAxv*0^TXV&u#a~{gpoZTpS_FTj87hDTG
z%P;wM-7@R^94S?eMx|!CJcqv9Jg;up4X8K`%BanjYL3$cYss{lzU?%?Zupk#E;N01
z7L{BJYd63$@xX!$uI*bT->EvD4<?qMvzo5GXxFSc3uaxX&KxgKj!%Krs6?jbF8Y?|
zm#l{GE|;1Pjsa*?0CL`P-8af8eV5B>pow8}WzT~gJ2i8L@4I$+0c%0dx0Za!Rjl&D
zT&ZT`!$kBF)(C97G3x}nQ7*gIVraSa09c9_p`8DT=zB|NKuBUg+!XH}ilKumZLtVt
z@k1wecmig`zR4g+l;9%Za{hzpz+C*gw^Jd_ZTYO0^Pj>n!XocfS}aq{KYahf!0785
z4ir(yHOVtC#=j~#B@-q^zD`LIqW{8(@?3;G$PeVJ=n3>N2$j<!|Dh<jPb{5V`{lbL
z|DN0AFCLJ;Ci3Oy5^W8uu8Mp)?n{yXY#7OvV6IV#r^;Ru6Q2+pi++y=@k4u!NW7L~
kzjWc=<1WT02DtHS1S2&VH-KrG_sf4=46qgi3MuFR3+8`uJ^%m!

literal 0
HcmV?d00001

diff --git a/examples/asm/trap/trap.S b/examples/asm/trap/trap.S
new file mode 100644
index 00000000..e479f703
--- /dev/null
+++ b/examples/asm/trap/trap.S
@@ -0,0 +1,131 @@
+// trap.S
+// David_Harris@hmc.edu 11 May 2022
+//
+// Demonstrates setting up traps and invoking a trap handler.
+// The trap handler accepts timer interrupts and ecalls.
+// Saves cause and mtval into the signature
+// Ecall takes one argument in a0
+//   0: change privilege mode to user
+//   1: change privilege mode to supervisor
+//   3: change privilege mode to machine
+//   4: exit program with write tohost
+
+.EQU MTIME,    0x200bff8
+.EQU MTIMECMP, 0x2004000
+
+.global rvtest_entry_point
+
+rvtest_entry_point:
+    la sp, topofstack   # Initialize stack pointer (not used)
+    la s6, begin_signature  # s6 points to signature
+
+    # Set up timer
+    jal set_timecmp
+
+    # Set up interrupts
+    la t0, trap_handler
+    csrw mtvec, t0      # Initialize MTVEC to trap_handler
+    csrw mideleg, zero  # Don't delegate interrupts
+    csrw medeleg, zero  # Don't delegate exceptions
+    li t0, 0x080       
+    csrw mie, t0        # Enable machine timer interrupt
+    la t0, topoftrapstack 
+    csrw mscratch, t0   # MSCRATCH holds trap stack pointer
+    csrsi mstatus, 0x8  # Turn on mstatus.MIE global interrupt enable
+
+main:
+    # Change to user mode
+    li a0, 0            # a0 = 0: argument to enter user mode
+    ecall               # System call to enter user mode
+
+    # Wait for timer interrupts
+    li t0, 0x1000       # loop counter start value
+loop: 
+    addi t0, t0, -1     # decrement counter
+    bne t0, zero, loop  # and repeat until zero
+
+done:
+    li a0, 4            # argument to finish program    
+    ecall               # system call to finish program
+    j self_loop         # wait forever (not taken)
+
+set_timecmp:            # Set timer compare to 800 ticks later
+    la t0, MTIME
+    la t1, MTIMECMP
+    ld t0, 0(t0)        # Read current timer
+    addi t0, t0, 0x60   # Increment timer
+    sd t0, 0(t1)        # Set MTIMECMP = MTIME + 0x800
+    ret
+
+.align 4                # trap handlers must be aligned to multiple of 4
+trap_handler:
+    # Load trap handler stack pointer tp
+    csrrw tp, mscratch, tp  # swap MSCRATCH and tp
+    sd t0, 0(tp)        # Save t0 and t1 on the stack
+    sd t1, -8(tp)
+    csrr t0, mcause     # Check the cause
+    csrr t1, mtval      # And the trap value
+    sd t0, 0(s6)        # Save MCAUSE and MTVAL in the signature
+    sd t1, 8(s6)            
+    addi s6, s6, 16     
+    bgez t0, exception  # if msb is clear, it is an exception
+
+interrupt:              # must be a timer interrupt 
+    jal set_timecmp     # Increment compare for next timer interrupt
+    j trap_return       # clean up and return
+
+exception:
+    csrr t1, mepc   # add 4 to MEPC to determine return Address
+    addi t1, t1, 4
+    csrw mepc, t1
+    li t1, 8            # is it an ecall trap?
+    andi t0, t0, 0xFC # if CAUSE = 8, 9, or 11
+    bne t0, t1, trap_return # ignore other exceptions
+
+ecall:
+    li t0, 4
+    beq a0, t0, write_tohost    # call 4: terminate program
+    bltu a0, t0, changeprivilege    # calls 0-3: change privilege level
+    j trap_return       # ignore other ecalls
+
+changeprivilege:
+    li t0, 0x00001800   # mask off mstatus.MPP in bits 11-12
+    csrc mstatus, t0
+    andi a0, a0, 0x003  # only keep bottom two bits of argument
+    slli a0, a0, 11     # move into mstatus.MPP position
+    csrs mstatus, a0    # set mstatus.MPP with desired privilege
+
+trap_return:            # return from trap handler
+    ld t1, -8(tp)       # restore t1 and t0
+    ld t0, 0(tp)
+    csrrw tp, mscratch, tp  # restore tp
+    mret                # return from trap
+
+write_tohost:
+    la t1, tohost
+    li t0, 1            # 1 for success, 3 for failure
+    sd t0, 0(t1)        # send success code
+
+self_loop:
+    j self_loop         # wait
+    
+.section .tohost 
+tohost:                 # write to HTIF
+    .dword 0
+fromhost:
+    .dword 0
+
+.EQU XLEN,64
+begin_signature:
+    .fill 6*(XLEN/32),4,0xdeadbeef    # 
+end_signature:
+
+# Initialize stack with room for 512 bytes
+.bss
+    .space 512
+topofstack:
+# And another stack for the trap handler
+.bss   
+    .space 512
+topoftrapstack:
+
diff --git a/examples/asm/trap/trap.reference_output b/examples/asm/trap/trap.reference_output
new file mode 100644
index 00000000..ed4dbe0a
--- /dev/null
+++ b/examples/asm/trap/trap.reference_output
@@ -0,0 +1,6 @@
+000000000000000b
+0000000000000000
+8000000000000007
+0000000000000000
+0000000000000008
+0000000000000000